СДАМ ГИА: РЕШУ ЕГЭ
Образовательный портал для подготовки к экзаменам
Информатика
≡ информатика
сайты - меню - вход - новости




Задания
Версия для печати и копирования в MS Word
Задание 27 № 17391

Дана последовательность N целых положительных чисел. Рассматриваются все пары элементов последовательности, находящихся на расстоянии не меньше 6 (разница в индексах элементов должна быть 6 или более). Необходимо определить количество пар, сумма чисел в которых чётна.

Описание входных и выходных данных.

В первой строке входных данных задаётся количество чисел N (6 ≤ N ≤ 1000). В каждой из последующих N строк записано одно натуральное число, не превышающее 10 000.

Пример входных данных:

8

1

3

5

4

6

7

9

8

Пример выходных данных для приведённого выше примера входных данных:

1

Пояснение. Из 8 чисел можно составить 3 пары, удовлетворяющие условию. Это будут элементы с индексами 1 и 7, 1 и 8, 2 и 8. Для заданного набора чисел получаем пары (1, 9), (1, 8), (3, 8). Суммы чисел в этих парах равны 10, 9, 11. Чётная сумма — одна.

Напишите эффективную по времени и по памяти программу для решения этой задачи.

Программа считается эффективной по времени, если при увеличении количества исходных чисел N в k раз время работы программы увеличивается не более чем в k раз.

Программа считается эффективной по памяти, если память, необходимая для хранения всех переменных программы, не превышает 1 килобайта и не увеличивается с ростом N.

Максимальная оценка за правильную (не содержащую синтаксических ошибок и дающую правильный ответ при любых допустимых входных данных) программу, эффективную по времени и по памяти, — 4 балла.

Максимальная оценка за правильную программу, эффективную только по времени или только по памяти, — 3 балла.

Максимальная оценка за правильную программу, не удовлетворяющую требованиям эффективности, — 2 балла.

Вы можете сдать одну или две программы решения задачи. Если Вы сдадите две программы, каждая из них будет оцениваться независимо от другой, итоговой станет бо́льшая из двух оценок.

Перед текстом программы кратко опишите алгоритм решения. Укажите использованный язык программирования и его версию.

Решение.

Сумма двух чисел чётна, если эти числа имеют одинаковую чётность.

Будем подсчитывать отдельно количество чётных и нечётных элементов последовательности.

Эти счётчики будем вести без учёта 6 последних элементов. Для этого понадобится хранить последние 6 элементов. Остальные элементы последовательности можно не хранить, это обеспечивает эффективность по памяти. Для хранения 6 элементов можно использовать циклический массив, как показано в решении 1.

Будем рассматривать каждое введённое число как правый элемент возможной пары (первые 6 чисел не могут быть таким элементом) и в зависимости от его чётности определять количество подходящих пар

 

Решение 1. Правильная и эффективная программы на языке Паскаль (использован циклический массив):

 

const s=6; {требуемое расстояние между элементами}

var

    N: integer; {количество чисел}

    x: integer; {очередное число}

    a: array[0..s-1] of integer;

    n0, n1 : integer; {счётчики чётных и нечётных элементов}

    k: integer; {количество пар}

    i: integer; {счётчик для ввода}

    ia: integer; {текущий индекс в массиве a}

begin

    readln(N);

    {ввод первых s чисел}

    for i:=0 to s-1 do readln(a[i]); {ввод и обработка остальных значений}

    n0:=0; n1:=0;

    k := 0; ia:=0;

    for i:=s to N-1 do begin

        readln(x);

        if a[ia] mod 2 = 0 then n0 := n0 + 1

        else n1 := n1 + 1;

        if x mod 2 = 0 then k := k + n0

        else k := k + n1;

        a[ia] := x;

        ia := (ia+1) mod s

    end;

    writeln(k)

end.

 

Вместо циклического массива можно использовать сдвиги. В этом случае для вычисления всегда используется первый элемент массива, а новое число записывается в последний. Хотя этот алгоритм работает медленнее, чем алгоритм с циклическим массивом (для каждого элемента требуется 5 дополнительных присваиваний при сдвигах), основное требование эффективности здесь выполнено: при увеличении размера массива в k раз количество действий растёт не более чем в k раз. Ниже приводится пример такой программы

 

Решение 2. Правильная и эффективная программы на языке Паскаль (использован сдвиг массива)

 

const s=6; {требуемое расстояние между элементами}

var

    N: integer; {количество чисел}

    x: integer; {очередное число}

    a: array[1..s] of integer;

    n0,n1 : integer; {счётчики чётных и нечётных элементов}

    k: integer; {количество пар}

    i: integer; {счётчик для ввода}

    ia: integer; {счётчик для сдвига}

begin

    readln(N);

    {ввод первых s чисел}

    for i:=1 to s do readln(a[i]); {ввод и обработка остальных значений}

    n0:=0; n1:=0;

    k := 0; ia:=0;

    for i:=s+1 to N do begin

        readln(x);

        if a[1] mod 2 = 0 then n0 := n0 + 1

        else n1 := n1 + 1;

        if x mod 2 = 0 then k := k + n0

        else k := k + n1;

        for ia:=1 to s-1 do a[ia]:=a[ia+1];

        a[s] := x;

    end;

    writeln(k)

end.

 

Возможно также «лобовое» решение: запишем все исходные числа в массив, переберём все возможные пары и подсчитаем количество подходящих. Такое решение не является эффективным ни по памяти (требуемая память зависит от размера исходных данных), ни по времени (количество возможных пар, а значит, количество действий и время счёта с ростом количества исходных элементов растёт квадратично). Такая программа оценивается не выше 2 баллов.

 

Решение 3. Правильная, но неэффективная программы на языке Паскаль:

 

const s=6; {требуемое расстояние между элементами}

var

    N: integer; {количество чисел}

    a: array [1..1000] of integer; {исходные данные}

    k: integer; {количество пар}

    i,j: integer;

begin

    readln(N);

    for i:=1 to N do readln(a[i]);

    k :=0;

    for i := 1 to N-s do begin

        for j := i+s to N do begin

            if (a[i]+a[j]) mod 2 = 0

                then k := k + 1

        end

    end;

    writeln(k)

end.