Дан набор из N целых положительных чисел. Из этих чисел формируются все возможные пары (парой считаются два элемента, которые находятся на разных местах в наборе, порядок чисел в паре не учитывается), в каждой паре вычисляются сумма и произведение элементов. Необходимо определить количество пар, у которых сумма нечётна, а произведение делится на 3.
Напишите эффективную по времени и по памяти программу для решения этой задачи.
Программа считается эффективной по времени, если при увеличении количества исходных чисел N в k раз время работы программы увеличивается не более чем в k раз.
Программа считается эффективной по памяти, если память, необходимая для хранения всех переменных программы, не превышает одного килобайта и не увеличивается с ростом N.
Максимальная оценка за правильную (не содержащую синтаксических ошибок и дающую правильный ответ при любых допустимых входных данных) программу, эффективную по времени и по памяти, — 4 балла.
Максимальная оценка за правильную программу, эффективную только по времени или только по памяти, — 3 балла.
Максимальная оценка за правильную программу, не удовлетворяющую требованиям эффективности, — 2 балла.
Вы можете сдать одну или две программы решения задачи. Если Вы сдадите две программы, каждая из них будет оцениваться независимо от другой, итоговой станет бо́льшая из двух оценок.
Перед текстом программы кратко опишите алгоритм решения. Укажите использованный язык программирования и его версию.
Описание входных и выходных данных.
В первой строке входных данных задаётся количество чисел N (1 ≤ N ≤ 1000). В каждой из последующих N строк записано одно натуральное число, не превышающее 100.
Пример входных данных:
4
1
2
3
4
Пример выходных данных для приведённого выше примера входных данных:
2
Из четырёх чисел можно составить 6 пар. В данном случае условиям удовлетворяют две пары: (2, 3) и (3, 4). Суммы чисел в этих парах (5 и 7) нечётны, а произведения (6 и 12) делятся на 3. У всех остальных пар как минимум одно из этих условий не выполняется.
Чтобы сумма двух чисел было нечётной, одно из них должно быть чётным, а другое — нечётным. Чтобы произведение двух чисел делилось на 3, хотя бы одно из этих чисел должно делиться на 3.
Разобьём все числа исходного набора на 4 группы, в зависимости от их чётности и делимости на 3. Сами числа можно не хранить, достаточно при вводе определить остаток от деления очередного числа на 2 и на 3 и увеличить соответствующий счётчик. Таким образом, независимо от количества чисел в исходном наборе, после чтения исходных данных для хранения необходимой информации хватит четырёх счётчиков, и программа получится эффективной по памяти.
Пусть в результате подсчёта получилось, что в наборе данных
m1 нечётных чисел, не кратных 3;
m2 чётных чисел, не кратных 3;
m3 нечётных чисел, кратных 3;
m6 чётных чисел, кратных 3.
Тогда количество удовлетворяющих условию пар можно определить по формуле m1m6 + m2m3 + m3m6.
Ниже приведена реализующая описанный выше алгоритм программа на языке Паскаль (использована версия PascalABC).
Пример правильной и эффективной программы на языке Паскаль:
var
N: integer; {количество чисел}
a: integer; {очередное число}
m1: integer; {нечётные, не кратные 3}
m2: integer; {чётные, не кратные 3}
m3: integer; {нечётные, кратные 3}
m6: integer; {чётные, кратные 3}
s: integer; {количество пар}
i: integer;
begin
m1 := 0; m2 := 0; m3 := 0; m6 := 0;
readln(N);
for i:=0 to N−1 do begin
readln(a);
if a mod 2 = 0 then begin
if a mod 3 = 0 then m6 := m6 + 1
else m2 := m2 + 1;
end
else begin
if a mod 3 = 0 then m3 := m3 + 1
else m1 := m1 + 1;
end
end;
s := m1 * m6 + m2 * m3 + m3 * m6;
writeln(s);
end.
Возможно также «лобовое» решение: запишем все исходные числа в массив, переберём все возможные пары и подсчитаем количество подходящих. Такое решение не является эффективным ни по памяти (требуемая память зависит от размера исходных данных), ни по времени (количество возможных пар, а значит, количество действий и время счёта с ростом количества исходных элементов растёт квадратично). Такая программа оценивается не выше двух баллов.
Ниже приведена реализующая описанный выше алгоритм программа на языке Паскаль (использована версия PascalABC)
Пример правильной, но неэффективной программы на языке Паскаль
var
N: integer; {количество чисел}
a: array [1..1000] of integer; {исходные данные}
s: integer; {количество пар}
i, j: integer;
begin
readln(N);
for i := 1 to N do readln(a[i]);
s := 0;
for i := 1 to N − 1 do begin
for j := i + 1 to N do begin
if ((a[i] + a[j]) mod 2 = 1) and ((a[i]*a[j]) mod 3 = 0) then s := s + 1;
end
end;
writeln(s);
end.
Приводим эффективное решение Николая Артюхина на C++.
#include <iostream>
using namespace std;
int main()
{
int n, x, kch3=0, kn3=0,kch=0,kn=0, k=0;
cin >> n;
for(int i=0;i<n;i++){
cin >> x;
if((x%3==0)&&(x%2==0)) kch3++;
else if((x%3==0)&&(x%2!=0)) kn3++;
else if((x%3!=0)&&(x%2==0)) kch++;
else if((x%3!=0)&&(x%2!=0)) kn++;
}
k=kch3*kn+kch3*kn3+kn3*kch;
cout << k;
return 0;
}
Приводим эффективное решение Игоря Кудашева на Python 3.
n = int(input())
x1 = 0
x2 = 0
x31 = 0
x32 = 0
for i in range(n):
x = int(input())
if x % 3 == 0:
if x % 2 != 0: x31 += 1
else: x32 += 1
elif x % 2 == 0: x2 += 1
else: x1 += 1
print(x31 * (x32 + x2) + x32 * x1)