Ре­ше­ние. Разобьём все числа ис­ход­но­го на­бо­ра на 7 групп по зна­че­нию остат­ка от де­ле­ния на 7 и под­счи­та­ем ко­ли­че­ство чисел в каж­дой груп­пе. Сами числа можно не хра­нить, до­ста­точ­но при вводе опре­де­лить оста­ток от де­ле­ния оче­ред­но­го числа на 7 и уве­ли­чить со­от­вет­ству­ю­щий счётчик. Таким об­ра­зом, не­за­ви­си­мо от ко­ли­че­ства чисел в ис­ход­ном на­бо­ре, после чте­ния ис­ход­ных дан­ных для хра­не­ния не­об­хо­ди­мой ин­фор­ма­ции хва­тит мас­си­ва из 7 эле­мен­тов и про­грам­ма по­лу­чит­ся эф­фек­тив­ной по па­мя­ти.

Чтобы сумма двух чисел де­ли­лась на 7, они оба долж­ны де­лить­ся на 7 либо сумма их остат­ков от де­ле­ния на 7 долж­на быть равна 7. Зная ко­ли­че­ство эле­мен­тов для каж­до­го остат­ка, можно опре­де­лить ко­ли­че­ство пар.

Ниже при­ве­де­на ре­а­ли­зу­ю­щая опи­сан­ный выше ал­го­ритм про­грам­ма на языке Пас­каль (ис­поль­зо­ва­на вер­сия PascalABC)

При­мер пра­виль­ной и эф­фек­тив­ной про­грам­мы на языке Пас­каль

var

    N: integer; {ко­ли­че­ство чисел}

    a: integer; {оче­ред­ное число}

    d: array [0..6] of integer; {груп­пы по остат­кам}

    s: integer; {ко­ли­че­ство пар}

    i: integer;

begin

    for i:=0 to 6 do d[i]:=0;

    readln(N);

    for i:=1 to N do begin

        readln(a);

        inc(d[a mod 7])

    end;

    s := d[0]*(d[0]-1) div 2;

    for i:=1 to 3 do s := s + d[i]*d[7-i];

    writeln(s)

end.

Воз­мож­но также «ло­бо­вое» ре­ше­ние: за­пи­шем все ис­ход­ные числа в мас­сив, пе­ре­берём все воз­мож­ные пары и под­счи­та­ем ко­ли­че­ство под­хо­дя­щих. Такое ре­ше­ние не яв­ля­ет­ся эф­фек­тив­ным ни по па­мя­ти (тре­бу­е­мая па­мять за­ви­сит от раз­ме­ра ис­ход­ных дан­ных), ни по вре­ме­ни (ко­ли­че­ство воз­мож­ных пар, а зна­чит, ко­ли­че­ство дей­ствий и время счёта с ро­стом ко­ли­че­ства ис­ход­ных эле­мен­тов растёт квад­ра­тич­но). Такая про­грам­ма оце­ни­ва­ет­ся не выше 2 бал­лов.

Ниже при­ве­де­на ре­а­ли­зу­ю­щая опи­сан­ный выше ал­го­ритм про­грам­ма на языке Пас­каль (ис­поль­зо­ва­на вер­сия PascalABC)

При­мер пра­виль­ной, но не­эф­фек­тив­ной про­грам­мы на языке Пас­каль

var

    N: integer; {ко­ли­че­ство чисел}

    a: array [1..1000] of integer; {ис­ход­ные дан­ные}

    s: integer; {ко­ли­че­ство пар}

    i,j: integer;

begin

    readln(N);

    for i:=1 to N do readln(a[i]);

    s :=0;

    for i := 1 to N-1 do begin

        for j := i+1 to N do begin

            if (a[i]+a[j]) mod 7 = 0

                then s := s + 1

        end

    end;

    writeln(s)

end.